通达信量比选股指标公式，判断市场的活跃程度和资金流向

量比是股票分析中常用的一个指标，指的是今天开盘后平均每分钟的成交量与前5天平均每分钟成交量之比，用于衡量成交量的相对水平。

量比可以用来辅助判断当前市场的活跃程度和资金流向。当量比的数值比较大时，当前成交量较前5天平均水平更高，可能意味着市场情绪的激烈变化或者主力资金的介入；当量比的数值比较小时，当前成交量较前5天平均水平更低，可能意味着市场情绪的冷淡或者主力资金的离场。

对于量比可以做一些划分，一般来说：

量比0.5以下，地量，市场不活跃，但是也可能暗藏机会；

量比0.8-1.5，正常成交量；

量比1.5-2.5，温和放量；

量比2.5-5，明显放量；

量比5-10倍，剧烈放量；

量比10倍以上，巨量，小心物极必反。

一、如何查看量比

1、盘口查看

2、分时图查看：在通达信的分时图界面，输入“量比”或者“.506”，双击“量比(多空)指标”，就可以加载到分时图副图。

如果要在K线图查看，就需要自己编写量比指标了。

二、量比指标公式（1分钟副图）

量比计算公式：量比 =（当前成交量 / 开盘分钟数）/ 前5天平均每分钟成交量

{仅适用于1分钟图，需要加载满1200根1分钟K线}

D:=DATE<>REF(DATE,1);{今天开盘第一根K线(1分钟图)}

T:=BARSLAST(D);

V1:=SUM(VOL,T+1);{开盘到现在的分钟数}

JL1:=V1/(T+1);{今天开盘后平均每分钟的成交量}

V2:=SUM(VOL,T+1201)-SUM(VOL,T+1);{前5天总成交量累加(1分钟图)}

JL2:=V2/1200;{前5天平均每分钟成交量}

量比:IF(PERIOD=0,JL1/JL2,DRAWNULL);{只在1分钟图显示}

三、量比指标公式（日线副图）

量比显示分两种情况，今天的量比LB1实时显示，和盘口显示的量比数值相同。计算比较复杂，不想算LB1可以用即时行情函数DYNAINFO(17)，直接调用量比的数据。今天之前的量比LB2计算就简单一点，之前的成交量已经不会再变化，直接用成交量除以前5天的平均成交量。

{仅适用于日线}

JL1:=V/FROMOPEN;{今天开盘后平均每分钟的成交量}

JL2:=REF(MA(V/TOTALFZNUM,5),1);{前5天平均每分钟成交量}

LB1:=JL1/JL2;

LB2:=V/REF(MA(V,5),1);

LB:=IF(ISLASTBAR,LB1,LB2);

量比:LB,NODRAW;

地量:=LB<0.5;{量比0.5以下，地量}

正常:=LB>=0.8 AND LB<1.5;{量比0.8-1.5，正常量}

温和:=LB>=1.5 AND LB<2.5;{量比1.5-2.5，温和放量}

明显:=LB>=2.5 AND LB<5;{量价2.5-5，明显放量}

剧烈:=LB>=5 AND LB<10;{量比5-10，剧烈放量}

巨量:=LB>=10;{量比10倍以上，巨量}

STICKLINE(C>=O,0,LB,2,1),COLORRED;

STICKLINE(C<O,0,LB,2,0),COLORCYAN;

STICKLINE(地量,0,LB,2,0),COLORBLUE;{地量，蓝色柱线}

STICKLINE(温和,0,LB,2,0),COLORYELLOW;{温和放量，黄色柱线}

STICKLINE(明显,0,LB,2,0),COLORMAGENTA;{明显放量，洋红色柱线}

STICKLINE(剧烈,0,LB,2,0),COLORRED;{剧烈放量红色柱线}

STICKLINE(巨量,0,LB,2,0),COLORFF0080;{巨量，紫色柱线}

DRAWTEXT(明显,LB*1.1,'明显放量'),COLORMAGENTA;

DRAWTEXT(剧烈,LB*1.1,'剧烈放量'),COLORRED;

DRAWTEXT(巨量,LB*1.1,'巨量'),COLORFF0080;

NOTEXT1:1.5,COLORYELLOW;

NOTEXT2:2.5,COLORMAGENTA;

NOTEXT3:5,COLORRED;

四、量比选股公式

适用于日线的量比选股公式比较简单，N=1就是量比大于1选股公式，N=2就是量比大于2选股公式，N的值可以自己调整。

N:=1;

LB:=V/REF(MA(V,5),1);

XG:LB>N;

{仅适用于日线};

友情提醒：本文仅供学习交流技术指标公式，不构成任何投资建议。投资有风险，入市需谨慎。