在这里插入图片描述

在windows 11中，可以在【此电脑】中任意文件夹中鼠标右键，可能直接在当前目录打开【终端】。用久也感觉还是很方便的。
与是在macOS中，我也想得到类似的功能。如何实现记录下来。

实战过程

我的实战环境是：
操作系统：macOS Venture 13.4
终端：iTerm2

iTermHere.scpt

使用你喜欢的任意文本编辑器创建一个脚本：
~/Library/Scripts/iTermHere.scpt
这个脚本路径保存在哪里都可以，选一个你喜欢的路径就可以了。
脚本的内容如下：


(* 

    Open Terminal Here 
     
    A toolbar script for Mac OS X 10.3+
     
    Written by Brian Schlining
	*)


property debug : false

-- when the toolbar script icon is clicked 
-- 
on run
	tell application "Finder"
		try
			set this_folder to (the target of the front window) as alias
		on error
			set this_folder to startup disk
		end try
		
		my process_item(this_folder)
		
	end tell
end run


-- This handler processes folders dropped onto the toolbar script icon 
-- 
on open these_items
	repeat with i from 1 to the count of these_items
		set this_item to item i of these_items
		my process_item(this_item)
	end repeat
end open


-- this subroutine processes does the actual work 
-- this version can handle this weirdo case: a folder named "te'st"ö te%s`t"

on process_item(this_item)
	
	set thePath to quoted form of POSIX path of this_item
	set theCmd to "cd " & thePath & ";clear;"
	
	tell application "iTerm"
		activate
		-- just open a terminal and cd to thePath
		--set newWindow to (create window with default profile)
		
		set aWindow to current window
		
		if aWindow is equal to missing value then
			set aWindow to (create window with default profile)
		else
			tell aWindow
				set t to (create tab with default profile)
			end tell
		end if
		
		
		tell current session of aWindow
			write text "cd " & thePath & ";clear;"
		end tell
		
	end tell
	
	
end process_item