idea/DataGrip 自定义自动生成pojo类脚本,集成lombok方式,简化开发

前言

自定义的原因: idea/datagrip 自带的脚本生成的pojo类需要大量的更改,不太方便,因此对此文件做了一定的修改.
主要还是参考了此篇博客,不过由于与我想要的结果还有所差距,所以进行了一定的添加和修改

https://blog.csdn.net/qq_34371461/article/details/80571281

修改后生成实体类的结果如下

建表语句如下

create table if not exists tab_room
(
    room_id       int primary key  not null comment '房间号码',
    sex           char      default '无'          not null comment '可入住性别',
    num_people    int       default 0            not null comment '可入住人数',
    room_cost       decimal   default 0            not null comment '房间的费用 元/天',
    create_time   timestamp default current_timestamp comment '创建时间',
    update_time   timestamp default current_timestamp comment '更新时间',
    other_remarks varchar(200)  default '无' comment '其它备注'
)
    comment '房间表' default character set utf8;

具体使用

1. 连接mysql后效果如下

2. 选择你具体要生成实体类的表

3. 点击后会跳转到一个目录,添加一个文件

4. 把如下类容完整的拷贝进去

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.io.*
import java.text.SimpleDateFormat

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */
packageName = ""
//映射字段类型(可自主修改)
typeMapping = [
        (~/(?i)tinyint|smallint|mediumint/)      : "Integer",
        (~/(?i)int/)                             : "Long",
        (~/(?i)bool|boolean|bit/)                : "Boolean",
        (~/(?i)float|double|decimal|real/)       : "Double",
        (~/(?i)datetime|timestamp|date|time/)    : "Date",
        (~/(?i)blob|binary|bfile|clob|raw|image/): "InputStream",
        (~/(?i)/)                                : "String"
]


FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaClassName(table.getName(), true)
    def fields = calcFields(table)
    packageName = getPackageName(dir)
    PrintWriter printWriter = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "UTF-8"))
    printWriter.withPrintWriter {out -> generate(out, className, fields,table)}

//    new File(dir, className + ".java").withPrintWriter { out -> generate(out, className, fields,table) }
}

// 获取包所在文件夹路径
def getPackageName(dir) {
    return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}
//添加导包
def generate(out, className, fields,table) {
    out.println "package $packageName"
    out.println ""
    out.println "import javax.persistence.*;"
    out.println "import java.io.Serializable;"
    out.println "import lombok.*;"
    out.println "import javax.persistence.Id;"
    Set types = new HashSet()

    fields.each() {
        types.add(it.type)
    }

    if (types.contains("Date")) {
        out.println "import java.util.Date;"
    }

    if (types.contains("InputStream")) {
        out.println "import java.io.InputStream;"
    }
    out.println ""
    //输出类注释和注解可自行添加和修改
    out.println "/**\n" +
            " * @author  dell\n" +
            " * @date "+ new SimpleDateFormat("yyyy-MM-dd").format(new Date()) + " \n" +
            " */"
    out.println ""
    out.println "@Data"
    out.println "@NoArgsConstructor"
    out.println "@AllArgsConstructor"
    out.println "@Entity"
    out.println "@Table (name =\""+table.getName() +"\")"
    out.println "public class $className  implements Serializable {"
    out.println ""
    out.println genSerialID()

    fields.each() {
        out.println ""
        // 输出注释
        if (isNotEmpty(it.commoent)) {
            out.println "\t/**"
            out.println "\t * ${it.commoent.toString()}"
            out.println "\t */"
        }
        if (it.annos != "") out.println "   ${it.annos}"

        if ((className + "_id").equalsIgnoreCase(it.colName) || "id".equalsIgnoreCase(it.colName)) {
            out.println "\t@Id"
        }

        if ("Date".equalsIgnoreCase(it.type)) {
            out.println '''\t@JsonFormat(pattern="yyyy-MM-dd HH:mm:ss",timezone = "GMT+8")'''
            out.println '''\t@DateTimeFormat(pattern = "yyyy-MM-dd HH:mm:ss")'''
        }

        // 输出成员变量
        out.println "\tprivate ${it.type} ${it.name};"

    }

    // 输出get/set方法
//    fields.each() {
//        out.println ""
//        out.println "\tpublic ${it.type} get${it.name.capitalize()}() {"
//        out.println "\t\treturn this.${it.name};"
//        out.println "\t}"
//        out.println ""
//
//        out.println "\tpublic void set${it.name.capitalize()}(${it.type} ${it.name}) {"
//        out.println "\t\tthis.${it.name} = ${it.name};"
//        out.println "\t}"
//    }
    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        def comm =[
                colName : col.getName(),
                name :  javaName(col.getName(), false),
                type : typeStr,
                commoent: col.getComment(),
                annos: "\t@Column(name = \""+col.getName()+"\" )"]
        fields += [comm]
    }
}

// 处理类名（这里是因为我的表都是以tab_命名的，所以需要处理去掉生成类名时的开头的tab_ 其它的类似具体详情可看代码，
// 如果你不需要那么请查找用到了 javaClassName这个方法的地方修改为 javaName 即可）
def javaClassName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    // 去除开头的tab,如果是以t开头可以把
    //3..s.size() - 1 中的 3.. 改为 1..
    //并且把后面的 capitalize || s.length() == 3 改为 capitalize || s.length() == 1
    //其它的以此类推
    s = s[3..s.size() - 1]
    capitalize || s.length() == 3? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def javaName(str, capitalize) {
//    def s = str.split(/(?<=[^\p{IsLetter}])/).collect { Case.LOWER.apply(it).capitalize() }
//            .join("").replaceAll(/[^\p{javaJavaIdentifierPart}]/, "_")
//    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

static String changeStyle(String str, boolean toCamel){
    if(!str || str.size() <= 1)
        return str

    if(toCamel){
        String r = str.toLowerCase().split('_').collect{cc -> Case.LOWER.apply(cc).capitalize()}.join('')
        return r[0].toLowerCase() + r[1..-1]
    }else{
        str = str[0].toLowerCase() + str[1..-1]
        return str.collect{cc -> ((char)cc).isUpperCase() ? '_' + cc.toLowerCase() : cc}.join('')
    }
}

static String genSerialID()
{
    return "\tprivate static final long serialVersionUID =  "+Math.abs(new Random().nextLong())+"L;"
}

5. 测试生成

6. 选择生成目录然后点击ok

7. 进入生成的文件夹就能看到你想要的内容了

8. 关于lombok (idea可直接在插件中下载)

<!-- 依赖springboot 项目中可以不指定版本号,其它项目需指定 -->
<dependency>
    <groupId>org.projectlombok</groupId>
    <artifactId>lombok</artifactId>
</dependency>

最后: 你学废了么?

如果对你有帮助,可以的话给个点赞收藏加关注,如果使用过程中遇到什么问题,可以给我留言.