Arduino提高篇21—RFID模块门禁设计

在这里插入图片描述

RFID可应用于门禁系统，我们可以把数据写入标签，然后将有权限的标签进行记录保存，当有用户标签被扫描时，进行身份信息读取比对，然后根据权限进行相应的操作。

本篇配合OLED屏幕来模拟门禁系统，只对标签的UID进行简单对比判断，当然你也可以设置好自己的密钥，然后将数据写入到标签，进行更加严谨的身份识别。

1. 实验材料

Uno R3开发板
配套USB数据线
面包板及配套连接线
OLED显示屏
RFID-RC522模块及配套S50白卡和异形卡

2. 实验步骤

1. 根据原理图搭建电路图。

RC522模块的3.3V、GND分别对应连接开发板的3.3V、GND，模块的MOSI、MISO、SCK分别连接开发板的SPI接口11、12、13，模块的SDA、RST分别连接开发板数字管脚10、9。OLED屏的VCC和GND分别连接开发板的3.3V和GND，OLED屏的SDA和SCL分别连接开发板A4和A5。

实验原理图如下图所示：

实验原理图

实物连接图如下图所示：

实物连接图

2. 新建sketch，拷贝如下代码替换自动生成的代码并进行保存。

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#include <SPI.h>
#include <MFRC522.h>


#define SS_PIN 10
#define RST_PIN 9

MFRC522 rfid(SS_PIN, RST_PIN);

#define OLED_RESET     4
Adafruit_SSD1306 oled(128, 64, &Wire, OLED_RESET);

byte nuidPICC[4]; //存储读取的UID
byte cardID[4] = {0x6D, 0xC5, 0x4D, 0x96};//存储有权限的卡ID

void setup() {

  Serial.begin(9600);
  SPI.begin();
  rfid.PCD_Init();
  Serial.println("RC522初始化完成...");


  oled.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  oled.setTextColor(WHITE);//开像素点发光
  oled.clearDisplay();//清屏
  oled.setTextSize(2); //设置字体大小
}


void loop() {
  oled.clearDisplay();//清屏
  oled.setCursor(15, 2);//设置显示位置
  oled.println("--RFID--");
  oled.setCursor(25, 40);//设置显示位置
  oled.println("SCAN...");
  oled.display(); // 开显示

  //搜索新卡
  if ( ! rfid.PICC_IsNewCardPresent())
    return;

  // 验证NUID是否可读
  if ( ! rfid.PICC_ReadCardSerial())
    return;

  MFRC522::PICC_Type piccType = rfid.PICC_GetType(rfid.uid.sak);

  // 检查是否MIFARE卡类型
  if (piccType != MFRC522::PICC_TYPE_MIFARE_MINI &&
      piccType != MFRC522::PICC_TYPE_MIFARE_1K &&
      piccType != MFRC522::PICC_TYPE_MIFARE_4K) {
    Serial.println("不支持读取此卡类型");
    return;
  }

  // 保存读取到的UID
  for (byte i = 0; i < 4; i++) {
    nuidPICC[i] = rfid.uid.uidByte[i];
  }

  Serial.print("十六进制UID：");
  printHex(rfid.uid.uidByte, rfid.uid.size);
  Serial.println();

  if (nuidPICC[0] == cardID[0] && nuidPICC[1] == cardID[1]
      && nuidPICC[2] == cardID[2] && nuidPICC[3] == cardID[3])
  {
    oled.clearDisplay();//清屏
    oled.setCursor(15, 2);//设置显示位置
    oled.println("--RFID--");
    oled.setCursor(25, 40);//设置显示位置
    oled.println("CHECK OK");
    oled.display(); // 开显示

    delay(1000);
    oled.clearDisplay();//清屏
    oled.setCursor(15, 2);//设置显示位置
    oled.println("--RFID--");
    oled.setCursor(25, 40);//设置显示位置
    oled.println("OPEN...");
    oled.display(); // 开显示
  } else {
    oled.clearDisplay();//清屏
    oled.setCursor(15, 2);//设置显示位置
    oled.println("--RFID--");
    oled.setCursor(15, 40);//设置显示位置
    oled.println("CHECK ERR");
    oled.display(); // 开显示
  }

  // 使放置在读卡区的IC卡进入休眠状态，不再重复读卡
  rfid.PICC_HaltA();

  // 停止读卡模块编码
  rfid.PCD_StopCrypto1();
  delay(3000);
}

// 十六进制输出
void printHex(byte *buffer, byte bufferSize) {
  for (byte i = 0; i < bufferSize; i++) {
    Serial.print(buffer[i] < 0x10 ? " 0" : " ");
    Serial.print(buffer[i], HEX);
  }
}