学習目標:
Unity Shaderのレンダリング順序における透明マテリアル
学習内容:
1. 透明度テスト
2. 透明ブレンド
3. レンダリングキュー
4. 透明モデル
理由: 一般的なレンダリングでは、レンダリング順序は深度バッファーに従って決定されますが、透明マテリアルは深度書き込みを閉じる必要があるため、透明マテリアルはキュー内の他のマテリアルの色を混合するため、通常のマテリアルの方法ではレンダリングできません。1 と 2 は、それぞれ透明性を実現する 2 つの方法について説明しています。
1. 透明度テスト
より極端なテストでは、フラグメントの透明度が特定のしきい値を満たさない場合、フラグメントは直接破棄されます。そうでない場合は、深度書き込みの無効化の問題に関係なく、不透明なフラグメントと同様にテストおよび書き込みが行われ、結果は完全に透明または不透明のみになります。
2. 透明ブレンド
このメソッドでは、実際の半透明効果を得ることができます。中心となるアイデアは、独自の透明度をカラー バッファに既に存在する色と混合することです。このメソッドの重要なポイントは、オブジェクトが透明 -> 不透明の順序でレンダリングされる場合、最初に不透明なオブジェクトをレンダリングし、次にカラー バッファ内の色を透明なフラグメントと混合することです。逆が不透明 -> 透明の場合、透明なフラグメントはレンダリングされないため、レンダリング キューは非常に重要です。
3. レンダリングキュー
レンダリング キューは、複数の車両が複数のグループに分けられ、キューのインデックス番号に従ってレンダリングされます。各キューには特定の機能があります。
上で述べたように、ディープリングメモリが使用できないため、レンダリング順序が非常に重要であるため、レンダリングキューが存在します。
4. 透明モデル
このプロジェクトは書籍に付属するモデルで、実際の効果は次のとおりです
透明な部分はテクスチャの特定の色分布です。上記の表示は透明度テスト方法を使用して行われます。表示されている 2 つの極端な点は、完全に消えるか、または見えるかのどちらかです。
コードは以下のように表示されます
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
Shader "Unity Shaders Book/Chapter 8/Alpha Test" {
Properties {
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_MainTex ("Main Tex", 2D) = "white" {}
_Cutoff ("Alpha Cutoff", Range(0, 1)) = 0.5
}
SubShader {
Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}//渲染队列名为AlphaTest,忽略投影器影响,规划到TransparentCutout这个组
Pass {
Tags { "LightMode"="ForwardBase" }//渲染模式是用前向渲染->还有一种叫延迟渲染
CGPROGRAM
#pragma vertex vert//顶点着色器
#pragma fragment frag//片元着色器
#include "Lighting.cginc"//添加内置变量
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
fixed _Cutoff;
struct a2v {//顶点着色器输入结构
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct v2f {//顶点着色器输出结构
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float3 worldPos : TEXCOORD1;
float2 uv : TEXCOORD2;
};
v2f vert(a2v v) {//顶点着色器
v2f o;//顺序分别为切线空间、世界空间、世界坐标、纹理坐标进行变换最后返回
o.pos = UnityObjectToClipPos(v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed4 texColor = tex2D(_MainTex, i.uv);//获取贴图坐标
// Alpha test
clip (texColor.a - _Cutoff);//如果不为负数则采用该片元,意义在于texColor为目标材质,Cutoff为材质参数,如果低于则表明为为透明材质
// Equal to
// if ((texColor.a - _Cutoff) < 0.0) {
// discard;//意义跟clip一样剔除掉该片元
// }
//计算环境光和漫反射将其计算后输出
fixed3 albedo = texColor.rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
return fixed4(ambient + diffuse, 1.0);
}
ENDCG
}
}
FallBack "Transparent/Cutout/VertexLit"
}
もう 1 つの方法は、透明度の混合です。中心となるアイデアは、カラー バッファー内の色と混合して、透明なフラグメントの色を取得することです。結果は次のようになり、透明度によってマテリアル全体が選択されます。
コードは以下のように表示されます
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
Shader "Unity Shaders Book/Chapter 8/Alpha Blend" {
Properties {
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_MainTex ("Main Tex", 2D) = "white" {}
_AlphaScale ("Alpha Scale", Range(0, 1)) = 1
}
SubShader {
Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
Pass {
Tags { "LightMode"="ForwardBase" }
ZWrite Off
Blend SrcAlpha OneMinusSrcAlpha
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
fixed _AlphaScale;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float3 worldPos : TEXCOORD1;
float2 uv : TEXCOORD2;
};
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed4 texColor = tex2D(_MainTex, i.uv);
fixed3 albedo = texColor.rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
return fixed4(ambient + diffuse, texColor.a * _AlphaScale);
}
ENDCG
}
}
FallBack "Transparent/VertexLit"
}
要約:
透明度を実現するには、透明度テストと透明度混合の 2 つの方法があります。核となる式は 1. 透明でない場合は表示されません。2. 最初に不透明なオブジェクトをレンダリングし、次にカラー バッファ内のデータを混合して透明なオブジェクトの色を取得します。一般に、どちらもレンダリングの順序に注意する必要があります