PowerDesigner uses note two (batch synchronize the content of the Name column to the comment)

'******************************************************************************
'* File:     name2comment.vbs
'* Title:    Name to Comment Conversion
'* Model:    Physical Data Model
'* Objects: Table, Column, View
'* Author:   steveguoshao
'* Created: 2013-11-29
'* Mod By:   
'* Modified:
'* Version: 1.0
'* Memo:     Modify from name2code.vbs
'******************************************************************************

Option   Explicit
ValidationMode   =   True
InteractiveMode   =   im_Batch

Dim   mdl   '   the   current   model

'   get   the   current   active   model
Set   mdl   =   ActiveModel
If   (mdl   Is   Nothing)   Then
  MsgBox   "There   is   no   current   Model "
ElseIf   Not   mdl.IsKindOf(PdPDM.cls_Model)   Then
  MsgBox   "The   current   model   is   not   an   Physical   Data   model. "
Else
  ProcessFolder   mdl
End   If

'   This   routine   copy   name   into   comment   for   each   table,   each   column   and   each   view
'   of   the   current   folder
Private   sub   ProcessFolder(folder)
  Dim   Tab   'running     table
  for   each   Tab   in   folder.tables
    if   not   tab.isShortcut   then
      tab.comment   =   tab.name
      Dim   col   '   running   column
      for   each   col   in   tab.columns
        col.comment= col.name
      next
    end   if
  next

  Dim   view   'running   view
  for   each   view   in   folder.Views
    if   not   view.isShortcut   then
      view.comment   =   view.name
    end   if
  next

  '   go   into   the   sub-packages
  Dim   f   '   running   folder
  For   Each   f   In   folder.Packages
    if   not   f.IsShortcut   then
      ProcessFolder   f
    end   if
  Next
end   sub

 

When designing the table structure in PowerDesigner, if you need to batch synchronize the contents of the Name column to the comment column of the corresponding field, you can use the following settings.

1. Open the designed ER diagram project and click [Tools]--->[Execute Commends]---->[Edit/Run Script] in the toolbar, as shown in the following figure:

 

 

 

2. The Run/Edit Script dialog box pops up, as shown below:

3. Copy the code at the beginning of this article, save it as the name2comment.vbs file, click the third "Open File" button in the toolbar above, select the script file just saved, as shown in the following figure, click the [Run] button, execute script

 

4. Close the window, and then open any table design, you will be pleasantly surprised to find that the content of the column's comment is the same as the content of the Name column.