PowerDesigner writes the Comment to the name and the name to the Comment pd7 and later versions are available

When using PowerDesigner to design the conceptual model and physical model of the database, generally write Chinese in NAME or Comment and English in Code. Name is used for display, Code is used in code, but the text in Comment will be saved to the Comment of the database Table or Column. When the Name already exists, it is very troublesome to write a Comment again. You can use the following code to solve this problem:

• Code 1: Copy the characters in Name to Comment
  
  

  Option   Explicit 
  ValidationMode   =   True 
  InteractiveMode   =   im_Batch

  Dim   mdl   '   the   current   model

  '   get   the   current   active   model 
  Set   mdl   =   ActiveModel 
  If   (mdl   Is   Nothing)   Then 
        MsgBox   "There   is   no   current   Model " 
  ElseIf   Not   mdl.IsKindOf(PdPDM.cls_Model)   Then 
        MsgBox   "The   current   model   is   not   an   Physical   Data   model. " 
  Else 
        ProcessFolder   mdl 
  End   If

  '   This   routine   copy   name   into   comment   for   each   table,   each   column   and   each   view 
  '   of   the   current   folder 
  Private   sub   ProcessFolder(folder) 
        Dim   Tab   'running     table 
        for   each   Tab   in   folder.tables 
              if   not   tab.isShortcut   then 
                    tab.comment   =   tab.name 
                    Dim   col   '   running   column 
                    for   each   col   in   tab.columns 
                          col.comment=   col.name 
                    next 
              end   if 
        next

        Dim   view   'running   view 
        for   each   view   in   folder.Views 
              if   not   view.isShortcut   then 
                    view.comment   =   view.name 
              end   if 
        next

        '   go   into   the   sub-packages 
        Dim   f   '   running   folder 
        For   Each   f   In   folder.Packages 
              if   not   f.IsShortcut   then 
                    ProcessFolder   f 
              end   if 
        Next 
  end   sub

--------------------------------------------

         In addition, when using REVERSE ENGINEER to reversely generate PDM from the database, the NAME and CODE of the table in the PDM are actually CODE. In order to replace the NAME with the Chinese Comment of the Table or Column in the database, the following script can be used:

• Code 2: Copy the characters in Comment to Name

  
  Option   Explicit 
  ValidationMode   =   True 
  InteractiveMode   =   im_Batch

  Dim   mdl   '   the   current   model

  '   get   the   current   active   model 
  Set   mdl   =   ActiveModel 
  If   (mdl   Is   Nothing)   Then 
        MsgBox   "There   is   no   current   Model " 
  ElseIf   Not   mdl.IsKindOf(PdPDM.cls_Model)   Then 
        MsgBox   "The   current   model   is   not   an   Physical   Data   model. " 
  Else 
        ProcessFolder   mdl 
  End   If

  Private   sub   ProcessFolder(folder) 
  On Error Resume Next
        Dim   Tab   'running     table 
        for   each   Tab   in   folder.tables 
              if   not   tab.isShortcut   then 
                    tab.name   =   tab.comment
                    Dim   col   '   running   column 
                    for   each   col   in   tab.columns 
                    if col.comment="" then
                    else
                          col.name=   col.comment 
                    end if
                    next 
              end   if 
        next

        Dim   view   'running   view 
        for   each   view   in   folder.Views 
              if   not   view.isShortcut   then 
                    view.name   =   view.comment 
              end   if 
        next

        '   go   into   the   sub-packages 
        Dim   f   '   running   folder 
        For   Each   f   In   folder.Packages 
              if   not   f.IsShortcut   then 
                    ProcessFolder   f 
              end   if 
        Next 
  end   sub

-----------------------------------------------------------------------

The above two pieces of code are VB scripts, and the methods used in PowerDesigner are:

    PowerDesigner->Tools->Execute Commands->Edit/Run Scripts

Just copy the code into it and execute it, it is to operate on the entire CDM or PDM