Unity ShaderLab特效教程 着色器实例 代码+详解注释 【显示模型边框、模型线条，模型网格的shader】

如果代码中有什么不清楚请查看以下基础知识

Shader基础知识

unity3d 中 七种坐标知识详解

一个用于显示显示模型边框、模型线条，模型网格的shader

原理依然很简单，在几何渲染器中，获取片元的三个顶点，再组合成线条数据传给片元渲染器中渲染。
翠花，上效果图！

左图为原图，右图为效果图。
细心的你一定发现了这个预览图的线框都是三角形的，这是因为片元就是三角形的，如果想只是沿着面的边如下图这样显示，就在代码中做一处小修改即可，代码中有详细描述

代码：

Shader "Unlit/line"
{
    //变量接口
    Properties
    {
        //线段长度
        _LineLength("Length",float) = 1.
        //线段颜色
        _LineColor("Color",COLOR) = (0,1,0,1)
    }
    //着色器正文
    SubShader
    {
        //着色器程序块
        Pass
        {
            Tags { "RenderType" = "Opaque" }
            LOD 200
 
            CGPROGRAM
                #pragma target 5.0
                //顶点着色器，用于处理位置信息
                #pragma vertex vert
                //片元着色器，用于处理颜色
                #pragma fragment frag
                //几何着色器，DirectX 10新增的，介于顶点和片元着色器之间的可选着色器
                #pragma geometry geo
                //引入空间转换宏
                #include "UnityCG.cginc"
 
                float _LineLength;
                fixed4 _LineColor;
                 
                //输入到顶点着色器的数据
                struct v2g
                {
                    //顶点位置
                    float4  pos       : POSITION;
                    //法线
                    float3  normal    : NORMAL;
                    //纹理坐
                    float2  tex0        : TEXCOORD0;
                };
                //输入到片元着色器的数据
                struct g2f
                {
                    //像素位置
                    float4  pos       : POSITION;
                    //纹理
                    float2  tex0        : TEXCOORD0;
                };
                
                //顶点着色器正文appdata_base是默认输入信息，输出的是经过转化到世界桌标的顶点和法线信息
                v2g vert(appdata_base v)
                {
                    v2g o;
                    //顶点位置 从模型空间转为裁剪空间
				    o.pos = UnityObjectToClipPos(v.vertex);
                    o.normal = v.normal;
                    //初始化纹理信息
                    o.tex0 = float2(0, 0);
                    return o;
                }
                //几何着色器，放在顶点和片元之间。
                //maxvertexcount设置从顶点着色器到几何着色器每次输出最大顶点数量
                //输入修饰有point、line、triangle、lineadj、triangleadj分别对应点、线、三角形、有临接的线段、有邻接的三角形
			    //inout输出修饰类型有PointStream、LineStream、TriangleStream，分别显示顶点、线段、三角面
                //输入顶点的信息，inout这里是将一个数据传入函数，在函数中的修改会返回到函数外的数据
                //一次接受triangle的3个顶点数据，输出为LineStream的3条线段
                [maxvertexcount(3)]
                void geo(triangle v2g vg[3], inout LineStream<g2f> ls)
                {
                    //轮询一个片元的三个顶点，如果不想显示三角形的分割线，就把i< 3改成2！
                    for (int i = 0; i < 3; i++)
                    {
                        //初始化一个像素信息
                        g2f g2f_1;
                        //获取每个顶点的位置
                        g2f_1.pos = vg[i].pos;
                        //初始化纹理
                        g2f_1.tex0 = float2(0.0f, 0.0f);
                        //将点压入线条数据
                        ls.Append(g2f_1);
                    }
                    ////即使点不够，也会终止一个循环，并重新开始
				    ls.RestartStrip();
                }
 
                //片元着色器，用于上色
                fixed4 frag(g2f input) : COLOR
                {
                    return _LineColor;
                }
            ENDCG
        }
    }
}