Unity ShaderLab特效教程 适用于贴图、sprite和ugui的2d着色器实例 代码+详解注释 【可调整峰、频率、速度颜色的光线脉冲曲线效果】

如果代码中有什么不清楚请查看以下基础知识

Shader基础知识

unity3d 中 七种坐标知识详解

可调整峰、频率、速度颜色的脉冲曲线效果

效果图

代码

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Custom/Curve"
{
	Properties
	{
        _MainTex ("贴图", 2D) = "white" {}
		_BackgroundColor ("背景颜色", Color) = (1, 1, 1, 1)
		_LineColor ("线颜色", Color) = (0, 0, 0, 1)
        _Offset_Y ("Y 偏移量", Range(0, 1)) = 0.2
        _Peak (" 峰值", Range(0, 1)) = 0.2
        _Frequency ("频率", Range(0, 100)) = 0.2
        _MoveSpeed ("流动速度", Range(0, 100)) = 0.2
        // peak value
        _LineSize ("光束宽度", Range(0, 100)) = 50
	}
	SubShader
	{
		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
            //从程序传染顶点渲染器的数据
			struct a2v
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};
            //从顶点渲染器传入片元渲染器的数据
			struct v2f
			{			
				float4 position : SV_POSITION;
				float2 uv : TEXCOORD0;
			};
 
			//格子背景
            sampler2D _MainTex;
			fixed4 _BackgroundColor;
			fixed4 _LineColor;
            fixed _Frequency;
            fixed _MoveSpeed;
            fixed _Peak;
			fixed _Offset_Y;
            fixed _LineSize;
            //顶点着色器
			v2f vert (a2v v)
			{
				v2f o;
                //将像素空间从模型转为裁剪空间
				o.position = UnityObjectToClipPos(v.vertex);
				o.uv = v.uv;
				return o;
			}
			//片段着色器
			fixed4 frag (v2f o) : COLOR
			{
				//范围(1, 51)，乘上100是扩大差距(中间最亮其他两边基本不亮)，加上1是防止0作为除数，同时确保最中间最亮
                //通过uv.y - 0.5获取一个区间由（0，1）变为（-0.5 ， 0.5）的值，通过abs 区间变为（0.5，0，0.5）,被0.5减后，变成了区间(0,0.5,0)的值
                //计算曲线相关的y轴信息
                float y =  o.uv.y + sin(_Time.y * _MoveSpeed + o.uv.x * _Frequency) * _Peak;
                //y轴偏移
                float uv_y = abs(y - _Offset_Y);
                //1是uv的高值是1， v 值的区间是(1/0.5=2 - 1/0.2=5 - 1/0.5=2)
				float v = 1 / (uv_y * (100-_LineSize));
                // 计算线的颜色
				fixed4 lineCol = fixed4(v, v, v, 1) * _LineColor;
                //计算贴图颜色
				fixed4 renderTex = tex2D(_MainTex, o.uv);
                //合成贴图、遮罩、线的像素
                return (renderTex) * _BackgroundColor + lineCol;
			}
			ENDCG
		}
	}
}