Tongdaxin's stock selection formula is a strategy for countering false breakthroughs by hitting highs before breaking through.

For breakthrough trading strategies, a common problem is that the stock price breaks through a certain key pressure level, but soon falls back to the original range. This is the so-called "false breakthrough".

For false breakthroughs, we can identify them from the following aspects:

1. Confirm the overall trend. If the market is in an obvious upward trend, then the possibility of a true breakthrough is higher; if the market is in a consolidation or downward trend, then the possibility of a false breakthrough is higher.

2. Observe whether the amplitude of the breakthrough clearly exceeds the pressure level. If the amplitude is relatively small or not obvious, the authenticity of the breakthrough needs to be questioned.

3. Whether the breakthrough is matched by trading volume. If the trading volume is relatively low during the breakthrough, you need to remain vigilant. It may be a false breakthrough.

4. Is the breakthrough sustainable? If it breaks through the key pressure level but quickly falls below the pressure level, it may be a false breakthrough.

Knowing how to identify false breakthroughs, we can take corresponding measures to reduce the impact of false breakthroughs:

We cannot accurately judge whether a breakthrough is a true breakthrough or a false breakthrough. There is a certain probability. Based on the judgment of the market situation, we can arrange reasonable positions and formulate detailed trading plans, including stop-profits, stop-losses, and position adjustments. strategies and risk management strategies. Avoid the market falling short of expectations, leading to emotional trading.

In addition, you can wait and see what happens when the price breaks through, waiting for further confirmation signals, such as the price falling back and stabilizing. If the stock price can generally remain above the original pressure level and stabilize after the breakthrough, the risk of false breakthroughs can be relatively reduced. And after stepping back, we can occupy a favorable position, which is convenient for us to set a stop loss. This article is based on this idea to write the stock selection formula for high rebound before breakthrough.

1.Return to the high before breaking throughMain chart indicator formula

T1:=HHVBARS(H,30);

HH:=REF(H,T1);

HH30:=HHV(H,30);

LL30:=LLV(L,30);

HL:=(HH30-LL30)/LL30*100;

A1:=CROSS(C,REF(HH,1));{Breakthrough of previous high}

A2:=V/REF(V,1)>1.2;{Increase volume}

A3:=REF(HL<20,1);{limit interval width}

AA:=A1 AND A2 AND A3;

TP:=FILTER(AA,20);

T2:=BARSLAST(TP);

MA5:=MA(C,5);

MA60:=MA(C,60);

DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);

DEA:=EMA(DIF,9);

MACD:=(DIF-DEA)*2;

B1:=REF(MACD,1)<MIN(MACD,REF(MACD,2));{MACD bar today is greater than yesterday, and the day before yesterday was also greater than yesterday}

B2:=EXIST(TP,T2+1);{There is a breakthrough}

B3:=T2>2 AND T2<30;{Limit the number of periods after the breakthrough}

B4:=HHV(H,T2+1)/REF(C,T2)<1.2;{Limit the increase after the breakthrough}

B5:=LLV(L,T2+1)/HHV(H,T2+1)>0.8;{Limit the amplitude of the callback from the highest point}

B6:=LLV(L,T2+1)>REF(L,T2)*0.98;{Limit the amplitude of falling below the previous high pressure level}

B7:=C/REF(C,T2)<1.1;{Limit the deviation from the closing price of the breakthrough K line}

B8:=C>MAX(MAX(MA5,MA60),O);

BB:=B1 AND B2 AND B3 AND B4 AND B5 AND B6 AND B7 AND B8;

XG:=FILTER(BB,50);

STICKLINE(XG,H,L,0,1),COLORYELLOW;

STICKLINE(XG,C,O,3,0),COLOR117777;

STICKLINE(XG,C,O,2.5,0),COLOR119999;

STICKLINE(XG,C,O,2,0),COLOR11BBBB;

STICKLINE(XG,C,O,1.5,0),COLOR11DDDD;

STICKLINE(XG,C,O,1,0),COLOR44FFFF;

DRAWICON(XG,L,11);

2.Stock selection formula for high return before breakthrough

T1:=HHVBARS(H,30);

HH:=REF(H,T1);

HH30:=HHV(H,30);

LL30:=LLV(L,30);

HL:=(HH30-LL30)/LL30*100;

A1:=CROSS(C,REF(HH,1));

A2:=V/REF(V,1)>1.2;

A3:=REF(HL<20,1);

AA:=A1 AND A2 AND A3;

TP:=FILTER(AA,20);

T2:=BARSLAST(TP);

MA5:=MA(C,5);

MA60:=MA(C,60);

DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);

DEA:=EMA(DIF,9);

MACD:=(DIF-DEA)*2;

B1:=REF(MACD,1)<MIN(MACD,REF(MACD,2));

B2:=EXIST(TP,T2+1);

B3:=T2>2 AND T2<30;

B4:=HHV(H,T2+1)/REF(C,T2)<1.2;

B5:=LLV(L,T2+1)/HHV(H,T2+1)>0.8;

B6:=LLV(L,T2+1)>REF(L,T2)*0.98;

B7:=C/REF(C,T2)<1.1;

B8:=C>MAX(MAX(MA5,MA60),O);

BB:=B1 AND B2 AND B3 AND B4 AND B5 AND B6 AND B7 AND B8;

XG:FILTER(BB,50);

Finally, let me explain that waiting for a retracement is just a strategy to deal with false breakthroughs, and it is not necessarily the best solution. Many breakthroughs are not confirmed by a retracement. In addition, due to the complexity of the market, the result of the stock selection formula of hitting highs before breaking through must be completely in line with the idea. The formula uses MACD bars, which is relatively sensitive. The signal triggered after a retracement may be too early. Other oscillators can be used to trigger the signal. It also includes the situation of stepping back after a breakthrough, but falling back below the pressure level. Of course, the amplitude of the fall back below is limited, so pay attention to the quality of the signal.

Friendly reminder: This article is only for learning and communicating technical indicator formulas and does not constitute any investment advice. Investment is risky, so be cautious when entering the market.