The reference to 37 sensors and actuators has been widely circulated on the Internet. In fact, there must be more than 37 sensor modules compatible with Arduino. In view of the fact that I have accumulated some sensor and actuator modules on hand, according to the concept of practice to get true knowledge (must be done), for the purpose of learning and communication, I am going to try a series of experiments one by one, regardless of success (the program goes through) or not, They will be recorded - small progress or unsolvable problems, hoping to inspire others.
[Arduino] 168 kinds of sensor module series experiments (data code + simulation programming + graphics programming)
Experiment 141: AS608 optical fingerprint recognition module smart lock / attendance access control development / fingerprint acquisition module
[Arduino] 168 sensor module series experiments (data code + simulation programming + graphics programming)
Experiment 141: AS608 Optical Fingerprint Recognition Module Smart Lock/Attendance Access Control Development/Fingerprint Acquisition Module
Experiment 5: Enter the serial number and delete the specified fingerprint template
Arduino experiment open source code
/*
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验一百四十一：AS608光学指纹识别模块 智能锁/考勤门禁开发/指纹采集模块
实验之五：输入序号，删除指定指纹模板
安装库：IDE—工具—管理库—搜索Adafruit-Fingerprint-Sensor-Library—安装
实验接线：
Vi +3.3V（请勿接3.3V以上电源，否则烧毁模块！）
TX 2
RX 3
GND GND
*/
#include <Adafruit_Fingerprint.h>
// On Leonardo/Micro or others with hardware serial, use those! #0 is green wire, #1 is white
// uncomment this line:
// #define mySerial Serial1
// For UNO and others without hardware serial, we must use software serial...
// pin #2 is IN from sensor (GREEN wire)
// pin #3 is OUT from arduino (WHITE wire)
// comment these two lines if using hardware serial
SoftwareSerial mySerial(2, 3);
Adafruit_Fingerprint finger = Adafruit_Fingerprint(&mySerial);
void setup()
{
Serial.begin(9600);
while (!Serial); // For Yun/Leo/Micro/Zero/...
delay(100);
Serial.println("\n\nDelete Finger");
// set the data rate for the sensor serial port
finger.begin(57600);
if (finger.verifyPassword()) {
Serial.println("Found fingerprint sensor!");
} else {
Serial.println("Did not find fingerprint sensor ");
while (1);
}
}
uint8_t readnumber(void) {
uint8_t num = 0;
while (num == 0) {
while (! Serial.available());
num = Serial.parseInt();
}
return num;
}
void loop() // run over and over again
{
Serial.println("lease type in the ID # (from 1 to 127) you want to delete...");
uint8_t id = readnumber();
if (id == 0) {
// ID #0 not allowed, try again!
return;
}
Serial.print("Deleting ID #");
Serial.println(id);
deleteFingerprint(id);
}
uint8_t deleteFingerprint(uint8_t id) {
uint8_t p = -1;
p = finger.deleteModel(id);
if (p == FINGERPRINT_OK) {
Serial.println("Deleted!");
} else if (p == FINGERPRINT_PACKETRECIEVEERR) {
Serial.println("Communication error");
return p;
} else if (p == FINGERPRINT_BADLOCATION) {
Serial.println("Could not delete in that location");
return p;
} else if (p == FINGERPRINT_FLASHERR) {
Serial.println("Error writing to flash");
return p;
} else {
Serial.print("Unknown error: 0x"); Serial.println(p, HEX);
return p;
}
}
Delete Finger
Found fingerprint sensor!
Please type in the ID # (from 1 to 127) you want to delete…
Remove Fingerprint
Find the Fingerprint Sensor!
Please enter the ID to delete (from 1 to 127)...
Delete ID#9
delete!
Please enter the ID (from 1 to 127) to delete. . .
Delete ID#8
delete!
Please enter the ID (from 1 to 127) to delete. . .
Delete ID#7
delete!
Please enter the ID (from 1 to 127) to delete. . .
Delete ID#6
delete!
Please enter the ID (from 1 to 127) to delete. . .
Delete ID#5
delete!
Please enter the ID (from 1 to 127) to delete. . .
Delete ID#4
delete!
Please enter the ID (from 1 to 127) to delete. . .
Delete ID#3
delete!
Please enter the ID (from 1 to 127) to delete. . .
Experiment 6: Delete all fingerprint templates
Arduino experiment open source code
/*
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验一百四十一：AS608光学指纹识别模块 智能锁/考勤门禁开发/指纹采集模块
实验之六：删除所有指纹模板
安装库：IDE—工具—管理库—搜索Adafruit-Fingerprint-Sensor-Library—安装
实验接线：
Vi +3.3V（请勿接3.3V以上电源，否则烧毁模块！）
TX 2
RX 3
GND GND
*/
#include <Adafruit_Fingerprint.h>
// On Leonardo/Micro or others with hardware serial, use those! #0 is green wire, #1 is white
// uncomment this line:
// #define mySerial Serial1
// For UNO and others without hardware serial, we must use software serial...
// pin #2 is IN from sensor (GREEN wire)
// pin #3 is OUT from arduino (WHITE wire)
// comment these two lines if using hardware serial
SoftwareSerial mySerial(2, 3);
Adafruit_Fingerprint finger = Adafruit_Fingerprint(&mySerial);
void setup()
{
Serial.begin(9600);
while (!Serial); // For Yun/Leo/Micro/Zero/...
delay(100);
Serial.println("\n\nDeleting all fingerprint templates!");
Serial.println("ress 'Y' key to continue");
while (1) {
if (Serial.available() && (Serial.read() == 'Y')) {
break;
}
}
// set the data rate for the sensor serial port
finger.begin(57600);
if (finger.verifyPassword()) {
Serial.println("Found fingerprint sensor!");
} else {
Serial.println("Did not find fingerprint sensor ");
while (1);
}
finger.emptyDatabase();
Serial.println("Now database is empty ");
}
void loop() {
}
Deleting all fingerprint templates!
Press "Y" key to continue
Found fingerprint sensor!
Now database is empty
Found fingerprint sensor!
Now the database is empty :)
The module interface
adopts 8-core 1.25 mm pitch single-row socket. The module has a built-in finger detection circuit, and the user can read the status pin TCH (WAK) to judge whether there is a finger pressed.
Pin No. Name Type Function Description
1 Vi In Positive input terminal of module power supply +3.3V (do not connect power supply above 3.3V, otherwise the module will be burned!)
2 TX Out Serial data output, connected to RX of MCU or TTL serial port.
3 RX In Serial data input, connected to TX of MCU or TTL serial port.
4 GND - Signal ground. Internally connected to power ground.
5 TCH Out Sensing signal output, the default high level is effective
6 UA In Touch sensing power input terminal, 3.3v power supply
7 D+ - USB D+
8 D- - USB D-
(7 pins, 8 pins are USB signal lines, use serial port control module can be left unused)
Appendix: AS608 optical fingerprint recognition module Adafruit_Fingerprint.h library file
#ifndef ADAFRUIT_FINGERPRINT_H
#define ADAFRUIT_FINGERPRINT_H
/*!
* @file Adafruit_Fingerprint.h
*/
#include "Arduino.h"
#if defined(__AVR__) || defined(ESP8266)
#include <SoftwareSerial.h>
#elif defined(FREEDOM_E300_HIFIVE1)
#include <SoftwareSerial32.h>
#define SoftwareSerial SoftwareSerial32
#endif
#define FINGERPRINT_OK 0x00 //!< Command execution is complete
#define FINGERPRINT_PACKETRECIEVEERR 0x01 //!< Error when receiving data package
#define FINGERPRINT_NOFINGER 0x02 //!< No finger on the sensor
#define FINGERPRINT_IMAGEFAIL 0x03 //!< Failed to enroll the finger
#define FINGERPRINT_IMAGEMESS \
0x06 //!< Failed to generate character file due to overly disorderly
//!< fingerprint image
#define FINGERPRINT_FEATUREFAIL \
0x07 //!< Failed to generate character file due to the lack of character point
//!< or small fingerprint image
#define FINGERPRINT_NOMATCH 0x08 //!< Finger doesn't match
#define FINGERPRINT_NOTFOUND 0x09 //!< Failed to find matching finger
#define FINGERPRINT_ENROLLMISMATCH \
0x0A //!< Failed to combine the character files
#define FINGERPRINT_BADLOCATION \
0x0B //!< Addressed PageID is beyond the finger library
#define FINGERPRINT_DBRANGEFAIL \
0x0C //!< Error when reading template from library or invalid template
#define FINGERPRINT_UPLOADFEATUREFAIL 0x0D //!< Error when uploading template
#define FINGERPRINT_PACKETRESPONSEFAIL \
0x0E //!< Module failed to receive the following data packages
#define FINGERPRINT_UPLOADFAIL 0x0F //!< Error when uploading image
#define FINGERPRINT_DELETEFAIL 0x10 //!< Failed to delete the template
#define FINGERPRINT_DBCLEARFAIL 0x11 //!< Failed to clear finger library
#define FINGERPRINT_PASSFAIL \
0x13 //!< Find whether the fingerprint passed or failed
#define FINGERPRINT_INVALIDIMAGE \
0x15 //!< Failed to generate image because of lac of valid primary image
#define FINGERPRINT_FLASHERR 0x18 //!< Error when writing flash
#define FINGERPRINT_INVALIDREG 0x1A //!< Invalid register number
#define FINGERPRINT_ADDRCODE 0x20 //!< Address code
#define FINGERPRINT_PASSVERIFY 0x21 //!< Verify the fingerprint passed
#define FINGERPRINT_STARTCODE \
0xEF01 //!< Fixed falue of EF01H; High byte transferred first
#define FINGERPRINT_COMMANDPACKET 0x1 //!< Command packet
#define FINGERPRINT_DATAPACKET \
0x2 //!< Data packet, must follow command packet or acknowledge packet
#define FINGERPRINT_ACKPACKET 0x7 //!< Acknowledge packet
#define FINGERPRINT_ENDDATAPACKET 0x8 //!< End of data packet
#define FINGERPRINT_TIMEOUT 0xFF //!< Timeout was reached
#define FINGERPRINT_BADPACKET 0xFE //!< Bad packet was sent
#define FINGERPRINT_GETIMAGE 0x01 //!< Collect finger image
#define FINGERPRINT_IMAGE2TZ 0x02 //!< Generate character file from image
#define FINGERPRINT_SEARCH 0x04 //!< Search for fingerprint in slot
#define FINGERPRINT_REGMODEL \
0x05 //!< Combine character files and generate template
#define FINGERPRINT_STORE 0x06 //!< Store template
#define FINGERPRINT_LOAD 0x07 //!< Read/load template
#define FINGERPRINT_UPLOAD 0x08 //!< Upload template
#define FINGERPRINT_DELETE 0x0C //!< Delete templates
#define FINGERPRINT_EMPTY 0x0D //!< Empty library
#define FINGERPRINT_READSYSPARAM 0x0F //!< Read system parameters
#define FINGERPRINT_SETPASSWORD 0x12 //!< Sets passwords
#define FINGERPRINT_VERIFYPASSWORD 0x13 //!< Verifies the password
#define FINGERPRINT_HISPEEDSEARCH \
0x1B //!< Asks the sensor to search for a matching fingerprint template to the
//!< last model generated
#define FINGERPRINT_TEMPLATECOUNT 0x1D //!< Read finger template numbers
#define FINGERPRINT_AURALEDCONFIG 0x35 //!< Aura LED control
#define FINGERPRINT_LEDON 0x50 //!< Turn on the onboard LED
#define FINGERPRINT_LEDOFF 0x51 //!< Turn off the onboard LED
#define FINGERPRINT_LED_BREATHING 0x01 //!< Breathing light
#define FINGERPRINT_LED_FLASHING 0x02 //!< Flashing light
#define FINGERPRINT_LED_ON 0x03 //!< Always on
#define FINGERPRINT_LED_OFF 0x04 //!< Always off
#define FINGERPRINT_LED_GRADUAL_ON 0x05 //!< Gradually on
#define FINGERPRINT_LED_GRADUAL_OFF 0x06 //!< Gradually off
#define FINGERPRINT_LED_RED 0x01 //!< Red LED
#define FINGERPRINT_LED_BLUE 0x02 //!< Blue LED
#define FINGERPRINT_LED_PURPLE 0x03 //!< Purple LED
//#define FINGERPRINT_DEBUG
#define DEFAULTTIMEOUT 1000 //!< UART reading timeout in milliseconds
///! Helper class to craft UART packets
struct Adafruit_Fingerprint_Packet {
/**************************************************************************/
/*!
[url=home.php?mod=space&uid=31641]@Brief[/url] Create a new UART-borne packet
@param type Command, data, ack type packet
@param length Size of payload
@param data Pointer to bytes of size length we will memcopy into the
internal buffer
*/
/**************************************************************************/
Adafruit_Fingerprint_Packet(uint8_t type, uint16_t length, uint8_t *data) {
this->start_code = FINGERPRINT_STARTCODE;
this->type = type;
this->length = length;
address[0] = 0xFF;
address[1] = 0xFF;
address[2] = 0xFF;
address[3] = 0xFF;
if (length < 64)
memcpy(this->data, data, length);
else
memcpy(this->data, data, 64);
}
uint16_t start_code; ///< "Wakeup" code for packet detection
uint8_t address[4]; ///< 32-bit Fingerprint sensor address
uint8_t type; ///< Type of packet
uint16_t length; ///< Length of packet
uint8_t data[64]; ///< The raw buffer for packet payload
};
///! Helper class to communicate with and keep state for fingerprint sensors
class Adafruit_Fingerprint {
public:
#if defined(__AVR__) || defined(ESP8266) || defined(FREEDOM_E300_HIFIVE1)
Adafruit_Fingerprint(SoftwareSerial *ss, uint32_t password = 0x0);
#endif
Adafruit_Fingerprint(HardwareSerial *hs, uint32_t password = 0x0);
Adafruit_Fingerprint(Stream *serial, uint32_t password = 0x0);
void begin(uint32_t baud);
boolean verifyPassword(void);
uint8_t getParameters(void);
uint8_t getImage(void);
uint8_t image2Tz(uint8_t slot = 1);
uint8_t createModel(void);
uint8_t emptyDatabase(void);
uint8_t storeModel(uint16_t id);
uint8_t loadModel(uint16_t id);
uint8_t getModel(void);
uint8_t deleteModel(uint16_t id);
uint8_t fingerFastSearch(void);
uint8_t fingerSearch(uint8_t slot = 1);
uint8_t getTemplateCount(void);
uint8_t setPassword(uint32_t password);
uint8_t LEDcontrol(bool on);
uint8_t LEDcontrol(uint8_t control, uint8_t speed, uint8_t coloridx,
uint8_t count = 0);
void writeStructuredPacket(const Adafruit_Fingerprint_Packet &p);
uint8_t getStructuredPacket(Adafruit_Fingerprint_Packet *p,
uint16_t timeout = DEFAULTTIMEOUT);
/// The matching location that is set by fingerFastSearch()
uint16_t fingerID;
/// The confidence of the fingerFastSearch() match, higher numbers are more
/// confidents
uint16_t confidence;
/// The number of stored templates in the sensor, set by getTemplateCount()
uint16_t templateCount;
uint16_t status_reg = 0x0; ///< The status register (set by getParameters)
uint16_t system_id = 0x0; ///< The system identifier (set by getParameters)
uint16_t capacity = 64; ///< The fingerprint capacity (set by getParameters)
uint16_t security_level = 0; ///< The security level (set by getParameters)
uint32_t device_addr =
0xFFFFFFFF; ///< The device address (set by getParameters)
uint16_t packet_len = 64; ///< The max packet length (set by getParameters)
uint16_t baud_rate = 57600; ///< The UART baud rate (set by getParameters)
private:
uint8_t checkPassword(void);
uint32_t thePassword;
uint32_t theAddress;
uint8_t recvPacket[20];
Stream *mySerial;
#if defined(__AVR__) || defined(ESP8266) || defined(FREEDOM_E300_HIFIVE1)
SoftwareSerial *swSerial;
#endif
HardwareSerial *hwSerial;
};
#endif
AS608 optical fingerprint identification module Adafruit_Fingerprint.cpp library file
/*!
* @file Adafruit_Fingerprint.cpp
*
* @mainpage Adafruit Fingerprint Sensor Library
*
* @section intro_sec Introduction
*
* This is a library for our optical Fingerprint sensor
*
* Designed specifically to work with the Adafruit Fingerprint sensor
* ----> http://www.adafruit.com/products/751
*
* These displays use TTL Serial to communicate, 2 pins are required to
* interface
* Adafruit invests time and resources providing this open source code,
* please support Adafruit and open-source hardware by purchasing
* products from Adafruit!
*
* @section author Author
*
* Written by Limor Fried/Ladyada for Adafruit Industries.
*
* @section license License
*
* BSD license, all text above must be included in any redistribution
*
*/
#include "Adafruit_Fingerprint.h"
//#define FINGERPRINT_DEBUG
/*!
* [url=home.php?mod=space&uid=31641]@Brief[/url] Gets the command packet
*/
#define GET_CMD_PACKET(...) \
uint8_t data[] = {
__VA_ARGS__}; \
Adafruit_Fingerprint_Packet packet(FINGERPRINT_COMMANDPACKET, sizeof(data), \
data); \
writeStructuredPacket(packet); \
if (getStructuredPacket(&packet) != FINGERPRINT_OK) \
return FINGERPRINT_PACKETRECIEVEERR; \
if (packet.type != FINGERPRINT_ACKPACKET) \
return FINGERPRINT_PACKETRECIEVEERR;
/*!
* @brief Sends the command packet
*/
#define SEND_CMD_PACKET(...) \
GET_CMD_PACKET(__VA_ARGS__); \
return packet.data[0];
/***************************************************************************
PUBLIC FUNCTIONS
***************************************************************************/
#if defined(__AVR__) || defined(ESP8266) || defined(FREEDOM_E300_HIFIVE1)
/**************************************************************************/
/*!
@brief Instantiates sensor with Software Serial
@param ss Pointer to SoftwareSerial object
@param password 32-bit integer password (default is 0)
*/
/**************************************************************************/
Adafruit_Fingerprint::Adafruit_Fingerprint(SoftwareSerial *ss,
uint32_t password) {
thePassword = password;
theAddress = 0xFFFFFFFF;
hwSerial = NULL;
swSerial = ss;
mySerial = swSerial;
}
#endif
/**************************************************************************/
/*!
@brief Instantiates sensor with Hardware Serial
@param hs Pointer to HardwareSerial object
@param password 32-bit integer password (default is 0)
*/
/**************************************************************************/
Adafruit_Fingerprint::Adafruit_Fingerprint(HardwareSerial *hs,
uint32_t password) {
thePassword = password;
theAddress = 0xFFFFFFFF;
#if defined(__AVR__) || defined(ESP8266) || defined(FREEDOM_E300_HIFIVE1)
swSerial = NULL;
#endif
hwSerial = hs;
mySerial = hwSerial;
}
/**************************************************************************/
/*!
@brief Instantiates sensor with a stream for Serial
@param serial Pointer to a Stream object
@param password 32-bit integer password (default is 0)
*/
/**************************************************************************/
Adafruit_Fingerprint::Adafruit_Fingerprint(Stream *serial, uint32_t password) {
thePassword = password;
theAddress = 0xFFFFFFFF;
hwSerial = NULL;
#if defined(__AVR__) || defined(ESP8266) || defined(FREEDOM_E300_HIFIVE1)
swSerial = NULL;
#endif
mySerial = serial;
}
/**************************************************************************/
/*!
@brief Initializes serial interface and baud rate
@param baudrate Sensor's UART baud rate (usually 57600, 9600 or 115200)
*/
/**************************************************************************/
void Adafruit_Fingerprint::begin(uint32_t baudrate) {
delay(1000); // one second delay to let the sensor 'boot up'
if (hwSerial)
hwSerial->begin(baudrate);
#if defined(__AVR__) || defined(ESP8266) || defined(FREEDOM_E300_HIFIVE1)
if (swSerial)
swSerial->begin(baudrate);
#endif
}
/**************************************************************************/
/*!
@brief Verifies the sensors' access password (default password is
0x0000000). A good way to also check if the sensors is active and responding
@returns True if password is correct
*/
/**************************************************************************/
boolean Adafruit_Fingerprint::verifyPassword(void) {
return checkPassword() == FINGERPRINT_OK;
}
uint8_t Adafruit_Fingerprint::checkPassword(void) {
GET_CMD_PACKET(FINGERPRINT_VERIFYPASSWORD, (uint8_t)(thePassword >> 24),
(uint8_t)(thePassword >> 16), (uint8_t)(thePassword >> 8),
(uint8_t)(thePassword & 0xFF));
if (packet.data[0] == FINGERPRINT_OK)
return FINGERPRINT_OK;
else
return FINGERPRINT_PACKETRECIEVEERR;
}
/**************************************************************************/
/*!
@brief Get the sensors parameters, fills in the member variables
status_reg, system_id, capacity, security_level, device_addr, packet_len
and baud_rate
@returns True if password is correct
*/
/**************************************************************************/
uint8_t Adafruit_Fingerprint::getParameters(void) {
GET_CMD_PACKET(FINGERPRINT_READSYSPARAM);
status_reg = ((uint16_t)packet.data[1] << 8) | packet.data[2];
system_id = ((uint16_t)packet.data[3] << 8) | packet.data[4];
capacity = ((uint16_t)packet.data[5] << 8) | packet.data[6];
security_level = ((uint16_t)packet.data[7] << 8) | packet.data[8];
device_addr = ((uint32_t)packet.data[9] << 24) |
((uint32_t)packet.data[10] << 16) |
((uint32_t)packet.data[11] << 8) | (uint32_t)packet.data[12];
packet_len = ((uint16_t)packet.data[13] << 8) | packet.data[14];
if (packet_len == 0) {
packet_len = 32;
} else if (packet_len == 1) {
packet_len = 64;
} else if (packet_len == 2) {
packet_len = 128;
} else if (packet_len == 3) {
packet_len = 256;
}
baud_rate = (((uint16_t)packet.data[15] << 8) | packet.data[16]) * 9600;
return packet.data[0];
}
/**************************************************************************/
/*!
@brief Ask the sensor to take an image of the finger pressed on surface
@returns <code>FINGERPRINT_OK</code> on success
@returns <code>FINGERPRINT_NOFINGER</code> if no finger detected
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
@returns <code>FINGERPRINT_IMAGEFAIL</code> on imaging error
*/
/**************************************************************************/
uint8_t Adafruit_Fingerprint::getImage(void) {
SEND_CMD_PACKET(FINGERPRINT_GETIMAGE);
}
/**************************************************************************/
/*!
@brief Ask the sensor to convert image to feature template
@param slot Location to place feature template (put one in 1 and another in
2 for verification to create model)
@returns <code>FINGERPRINT_OK</code> on success
@returns <code>FINGERPRINT_IMAGEMESS</code> if image is too messy
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
@returns <code>FINGERPRINT_FEATUREFAIL</code> on failure to identify
fingerprint features
@returns <code>FINGERPRINT_INVALIDIMAGE</code> on failure to identify
fingerprint features
*/
uint8_t Adafruit_Fingerprint::image2Tz(uint8_t slot) {
SEND_CMD_PACKET(FINGERPRINT_IMAGE2TZ, slot);
}
/**************************************************************************/
/*!
@brief Ask the sensor to take two print feature template and create a
model
@returns <code>FINGERPRINT_OK</code> on success
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
@returns <code>FINGERPRINT_ENROLLMISMATCH</code> on mismatch of fingerprints
*/
uint8_t Adafruit_Fingerprint::createModel(void) {
SEND_CMD_PACKET(FINGERPRINT_REGMODEL);
}
/**************************************************************************/
/*!
@brief Ask the sensor to store the calculated model for later matching
@param location The model location #
@returns <code>FINGERPRINT_OK</code> on success
@returns <code>FINGERPRINT_BADLOCATION</code> if the location is invalid
@returns <code>FINGERPRINT_FLASHERR</code> if the model couldn't be written
to flash memory
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
*/
uint8_t Adafruit_Fingerprint::storeModel(uint16_t location) {
SEND_CMD_PACKET(FINGERPRINT_STORE, 0x01, (uint8_t)(location >> 8),
(uint8_t)(location & 0xFF));
}
/**************************************************************************/
/*!
@brief Ask the sensor to load a fingerprint model from flash into buffer 1
@param location The model location #
@returns <code>FINGERPRINT_OK</code> on success
@returns <code>FINGERPRINT_BADLOCATION</code> if the location is invalid
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
*/
uint8_t Adafruit_Fingerprint::loadModel(uint16_t location) {
SEND_CMD_PACKET(FINGERPRINT_LOAD, 0x01, (uint8_t)(location >> 8),
(uint8_t)(location & 0xFF));
}
/**************************************************************************/
/*!
@brief Ask the sensor to transfer 256-byte fingerprint template from the
buffer to the UART
@returns <code>FINGERPRINT_OK</code> on success
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
*/
uint8_t Adafruit_Fingerprint::getModel(void) {
SEND_CMD_PACKET(FINGERPRINT_UPLOAD, 0x01);
}
/**************************************************************************/
/*!
@brief Ask the sensor to delete a model in memory
@param location The model location #
@returns <code>FINGERPRINT_OK</code> on success
@returns <code>FINGERPRINT_BADLOCATION</code> if the location is invalid
@returns <code>FINGERPRINT_FLASHERR</code> if the model couldn't be written
to flash memory
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
*/
uint8_t Adafruit_Fingerprint::deleteModel(uint16_t location) {
SEND_CMD_PACKET(FINGERPRINT_DELETE, (uint8_t)(location >> 8),
(uint8_t)(location & 0xFF), 0x00, 0x01);
}
/**************************************************************************/
/*!
@brief Ask the sensor to delete ALL models in memory
@returns <code>FINGERPRINT_OK</code> on success
@returns <code>FINGERPRINT_BADLOCATION</code> if the location is invalid
@returns <code>FINGERPRINT_FLASHERR</code> if the model couldn't be written
to flash memory
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
*/
uint8_t Adafruit_Fingerprint::emptyDatabase(void) {
SEND_CMD_PACKET(FINGERPRINT_EMPTY);
}
/**************************************************************************/
/*!
@brief Ask the sensor to search the current slot 1 fingerprint features to
match saved templates. The matching location is stored in <b>fingerID</b> and
the matching confidence in <b>confidence</b>
@returns <code>FINGERPRINT_OK</code> on fingerprint match success
@returns <code>FINGERPRINT_NOTFOUND</code> no match made
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
*/
/**************************************************************************/
uint8_t Adafruit_Fingerprint::fingerFastSearch(void) {
// high speed search of slot #1 starting at page 0x0000 and page #0x00A3
GET_CMD_PACKET(FINGERPRINT_HISPEEDSEARCH, 0x01, 0x00, 0x00, 0x00, 0xA3);
fingerID = 0xFFFF;
confidence = 0xFFFF;
fingerID = packet.data[1];
fingerID <<= 8;
fingerID |= packet.data[2];
confidence = packet.data[3];
confidence <<= 8;
confidence |= packet.data[4];
return packet.data[0];
}
/**************************************************************************/
/*!
@brief Control the built in LED
@param on True if you want LED on, False to turn LED off
@returns <code>FINGERPRINT_OK</code> on success
*/
/**************************************************************************/
uint8_t Adafruit_Fingerprint::LEDcontrol(bool on) {
if (on) {
SEND_CMD_PACKET(FINGERPRINT_LEDON);
} else {
SEND_CMD_PACKET(FINGERPRINT_LEDOFF);
}
}
/**************************************************************************/
/*!
@brief Control the built in Aura LED (if exists). Check datasheet/manual
for different colors and control codes available
@param control The control code (e.g. breathing, full on)
@param speed How fast to go through the breathing/blinking cycles
@param coloridx What color to light the indicator
@param count How many repeats of blinks/breathing cycles
@returns <code>FINGERPRINT_OK</code> on fingerprint match success
@returns <code>FINGERPRINT_NOTFOUND</code> no match made
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
*/
/**************************************************************************/
uint8_t Adafruit_Fingerprint::LEDcontrol(uint8_t control, uint8_t speed,
uint8_t coloridx, uint8_t count) {
SEND_CMD_PACKET(FINGERPRINT_AURALEDCONFIG, control, speed, coloridx, count);
}
/**************************************************************************/
/*!
@brief Ask the sensor to search the current slot fingerprint features to
match saved templates. The matching location is stored in <b>fingerID</b> and
the matching confidence in <b>confidence</b>
@param slot The slot to use for the print search, defaults to 1
@returns <code>FINGERPRINT_OK</code> on fingerprint match success
@returns <code>FINGERPRINT_NOTFOUND</code> no match made
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
*/
/**************************************************************************/
uint8_t Adafruit_Fingerprint::fingerSearch(uint8_t slot) {
// search of slot starting thru the capacity
GET_CMD_PACKET(FINGERPRINT_SEARCH, slot, 0x00, 0x00, (uint8_t)(capacity >> 8),
(uint8_t)(capacity & 0xFF));
fingerID = 0xFFFF;
confidence = 0xFFFF;
fingerID = packet.data[1];
fingerID <<= 8;
fingerID |= packet.data[2];
confidence = packet.data[3];
confidence <<= 8;
confidence |= packet.data[4];
return packet.data[0];
}
/**************************************************************************/
/*!
@brief Ask the sensor for the number of templates stored in memory. The
number is stored in <b>templateCount</b> on success.
@returns <code>FINGERPRINT_OK</code> on success
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
*/
/**************************************************************************/
uint8_t Adafruit_Fingerprint::getTemplateCount(void) {
GET_CMD_PACKET(FINGERPRINT_TEMPLATECOUNT);
templateCount = packet.data[1];
templateCount <<= 8;
templateCount |= packet.data[2];
return packet.data[0];
}
/**************************************************************************/
/*!
@brief Set the password on the sensor (future communication will require
password verification so don't forget it!!!)
@param password 32-bit password code
@returns <code>FINGERPRINT_OK</code> on success
@returns <code>FINGERPRINT_PACKETRECIEVEERR</code> on communication error
*/
/**************************************************************************/
uint8_t Adafruit_Fingerprint::setPassword(uint32_t password) {
SEND_CMD_PACKET(FINGERPRINT_SETPASSWORD, (password >> 24), (password >> 16),
(password >> 8), password);
}
/**************************************************************************/
/*!
@brief Helper function to process a packet and send it over UART to the
sensor
@param packet A structure containing the bytes to transmit
*/
/**************************************************************************/
void Adafruit_Fingerprint::writeStructuredPacket(
const Adafruit_Fingerprint_Packet &packet) {
mySerial->write((uint8_t)(packet.start_code >> 8));
mySerial->write((uint8_t)(packet.start_code & 0xFF));
mySerial->write(packet.address[0]);
mySerial->write(packet.address[1]);
mySerial->write(packet.address[2]);
mySerial->write(packet.address[3]);
mySerial->write(packet.type);
uint16_t wire_length = packet.length + 2;
mySerial->write((uint8_t)(wire_length >> 8));
mySerial->write((uint8_t)(wire_length & 0xFF));
#ifdef FINGERPRINT_DEBUG
Serial.print("-> 0x");
Serial.print((uint8_t)(packet.start_code >> 8), HEX);
Serial.print(", 0x");
Serial.print((uint8_t)(packet.start_code & 0xFF), HEX);
Serial.print(", 0x");
Serial.print(packet.address[0], HEX);
Serial.print(", 0x");
Serial.print(packet.address[1], HEX);
Serial.print(", 0x");
Serial.print(packet.address[2], HEX);
Serial.print(", 0x");
Serial.print(packet.address[3], HEX);
Serial.print(", 0x");
Serial.print(packet.type, HEX);
Serial.print(", 0x");
Serial.print((uint8_t)(wire_length >> 8), HEX);
Serial.print(", 0x");
Serial.print((uint8_t)(wire_length & 0xFF), HEX);
#endif
uint16_t sum = ((wire_length) >> 8) + ((wire_length)&0xFF) + packet.type;
for (uint8_t i = 0; i < packet.length; i++) {
mySerial->write(packet.data[i]);
sum += packet.data[i];
#ifdef FINGERPRINT_DEBUG
Serial.print(", 0x");
Serial.print(packet.data[i], HEX);
#endif
}
mySerial->write((uint8_t)(sum >> 8));
mySerial->write((uint8_t)(sum & 0xFF));
#ifdef FINGERPRINT_DEBUG
Serial.print(", 0x");
Serial.print((uint8_t)(sum >> 8), HEX);
Serial.print(", 0x");
Serial.println((uint8_t)(sum & 0xFF), HEX);
#endif
return;
}
/**************************************************************************/
/*!
@brief Helper function to receive data over UART from the sensor and
process it into a packet
@param packet A structure containing the bytes received
@param timeout how many milliseconds we're willing to wait
@returns <code>FINGERPRINT_OK</code> on success
@returns <code>FINGERPRINT_TIMEOUT</code> or
<code>FINGERPRINT_BADPACKET</code> on failure
*/
/**************************************************************************/
uint8_t
Adafruit_Fingerprint::getStructuredPacket(Adafruit_Fingerprint_Packet *packet,
uint16_t timeout) {
uint8_t byte;
uint16_t idx = 0, timer = 0;
#ifdef FINGERPRINT_DEBUG
Serial.print("<- ");
#endif
while (true) {
while (!mySerial->available()) {
delay(1);
timer++;
if (timer >= timeout) {
#ifdef FINGERPRINT_DEBUG
Serial.println("Timed out");
#endif
return FINGERPRINT_TIMEOUT;
}
}
byte = mySerial->read();
#ifdef FINGERPRINT_DEBUG
Serial.print("0x");
Serial.print(byte, HEX);
Serial.print(", ");
#endif
switch (idx) {
case 0:
if (byte != (FINGERPRINT_STARTCODE >> 8))
continue;
packet->start_code = (uint16_t)byte << 8;
break;
case 1:
packet->start_code |= byte;
if (packet->start_code != FINGERPRINT_STARTCODE)
return FINGERPRINT_BADPACKET;
break;
case 2:
case 3:
case 4:
case 5:
packet->address[idx - 2] = byte;
break;
case 6:
packet->type = byte;
break;
case 7:
packet->length = (uint16_t)byte << 8;
break;
case 8:
packet->length |= byte;
break;
default:
packet->data[idx - 9] = byte;
if ((idx - 8) == packet->length) {
#ifdef FINGERPRINT_DEBUG
Serial.println(" OK ");
#endif
return FINGERPRINT_OK;
}
break;
}
idx++;
}
// Shouldn't get here so...
return FINGERPRINT_BADPACKET;
}