Shader编程——高光漫反射模型

在实现该模型之前，我对shader和计算机图形学的知识可谓是空白，但是立志成为伟大游戏设计师的我又怎么能放弃对梦想的探寻，在网上寻找相应的课程，恰好看到一篇关于Shader入门的教程，学完之后觉得有所收获，这里记录也顺便分享给大家。一个基础的Shader编程，实现高光漫反射模型。

在正式编写shader代码前，我们首先得对一些基础知识做相应的了解，这里涉及到GPU的渲染流程和Shader编程的数学知识，在后面我会再写相应的博客介绍其内容，这里我将贴出Shader的源代码，在源码中我已经做了详尽的注释，还有不清楚的可以评论中问我，知无不言！

首先我们在Unity中创建一个Material材质球作为Shader的载体，之后我们再右键创建一个Shader编码文件，双击打开之后我们就可以编写啦，这里要提示，因为Shader语言是比较特殊的语言，所以用VS打开编写的话，代码提示和自动缩进都是没有的，这点比较痛苦，大家在编写的时候要养成良好的代码习惯，及时检查，避免不必要的错误~

Shader编程语法的基本格式框架如下：

了解框架后，高光漫反射模型的源码如下：

//名称，也声明了目录路径，默认为Customer
Shader "Unlit/UnlitShader005HalfSpec"
{
	//可以呈现在组件面板中的属性，格式为_Name("DisplayName",Type) = defaultValue
	Properties
	{
		_Diffuse("DiffuseColor",Color) = (1,1,1,1)//表面颜色，默认为白色
		_ValveIndex("ValveIndex",Range(0.0,1.0)) = 0.5 //Half Lambert Model
		_Specular("SpecularColor",Color) = (1,1,1,1)//高光颜色
		_Gloss("Glossness",Range(1.0,256.0)) = 8.0//光斑大小
	}
	//Shader的主要逻辑模块
	SubShader
	{
		Pass
		{
			//标签
			Tags{"LightMode" = "ForwardBase"}
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			//引用文件
			#include "Lighting.cginc"
			#include "UnityCG.cginc"
			//声明Properties中的属性
			fixed4 _Diffuse; //float 32bit ,half 16bit,fixed 11bit ; color [0-1]
			fixed _ValveIndex;
			fixed4 _Specular;
			half _Gloss;

			//application to vertex
			struct a2v
			{
				float4 vertex : POSITION; //一个4维的数据，代表的是位置信息  POSITION:语义 GPU在哪里去存取数据
				float3 normal : NORMAL;
			};

			//vertex to fragment
			struct v2f
			{
				float4 Pos : SV_POSITION;//SV_POSITION(POSITION) SV_TARGET(COLOR)
				float3 worldNormal : TEXCOORD0;//TEXCOORD0~7 储存一部分我们自定义的数据，类似寄存器
				float3 worldPos : TEXCOORD1;//vertex in world Space世界坐标下的顶点位置
			};

			//顶点着色器
			v2f vert(a2v v)
			{
				v2f o;
				o.Pos = UnityObjectToClipPos(v.vertex);//从模型空间变换到裁剪空间 Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
				o.worldPos = mul((float3x3)unity_ObjectToWorld, v.vertex);
				o.worldNormal = normalize(mul((float3x3)unity_ObjectToWorld,v.normal));//顶点法线从模型空间变换到世界空间
				return o;
			}
			//片元着色器
			fixed4 frag(v2f IN) : SV_TARGET
			{
				//光源到顶点的向量
				float3 lDir = normalize(UnityWorldSpaceLightDir(IN.worldPos));//用于平行光
				//环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

				//dot(IN.worldNormal, lDir) [-1,1]
				//dot(IN.worldNormal, lDir) * _ValveIndex [-_ValveIndex,_ValveIndex]
				fixed3 diffuse = _LightColor0 * _Diffuse * max(0,(dot(IN.worldNormal, lDir) * _ValveIndex + (1.0 - _ValveIndex)));//数组保证在0~1之间
				//viewDir,视角到顶点的向量
				float3 vDir = normalize(_WorldSpaceCameraPos.xyz - IN.worldPos.xyz);

				float3 halfDir = normalize(lDir + vDir);

				fixed3 specular = _LightColor0 * _Specular * pow(saturate(dot(IN.worldNormal, halfDir)), _Gloss);
				//最终输出结果=环境光+自身光+高光
				fixed3 _color = ambient + diffuse + specular;//ambient指的环境光 颜色相加

				return fixed4(_color, 1.0);
			}

			ENDCG
		}
	}
	//当本Shader的内容不被支持时，选用低级的Shader替换
	FallBack "Specular"//设置默认的阴影效果
}

编写完成后保存，我们可以在Unity中点击该脚本文件，若其中包含有语法错误，在Inspector面板中会报错，有红色字样的error提示第几行出现了错误。编写正确下，我们将该shader脚本拖到之前创建的material材质球上即可，之后再场景中创建物体再将材质球赋给该物体，添加上灯光，我们便可以观察其效果，下面是我所实现的效果，即表面呈现高光及漫反射

路漫漫其修远兮，这个模型只是带我们了解Shader编程的基础，真正要实现我们想要的更酷炫的效果还需求我们补充更多的知识，学习永无止境！

Shader编程——高光漫反射模型

猜你喜欢