表形式にフォーマットデータ

JJV：

私はコーディングの合計初心者ですが、grepのカウントデータからテーブルを生成する最も簡単な方法を疑問に思って。

このような私のgrepのカウント出力ファイルになります。

AAR34355.1
./006D_id70.m8:0
./20D_id70.m8:0
./28D_id70.m8:0
AAR38850.1
./006D_id70.m8:0
./20D_id70.m8:2
./28D_id70.m8:4
A13520.1
./006D_id70.m8:0
./20D_id70.m8:0
./28D_id70.m8:0

私はこのシリーズをもっと見て出力する必要があります。

            ./006D_id70.m8    ./20D_id70.m8    ./28D_id70.m8
AAR34355.1         0                0                 0
AAR38850.1         0                2                 4
A13520.1           0                0                 0

あるいは少なくとも同等の区切り。

私はこれにはかなり新しいですと、私の説明を許して。

データをこのようにフォーマットするのは比較的簡単な方法はありますか？

イスマイルOGUZ：

あなたはawkではすべて、リシェイプのgrepの出力には不要ということを行うことができます。検索するパターンが名前のファイルにリストされていると仮定するpatternsと、中に検索されるファイルがあるfile1、file2とfile3。名前のファイルに次のコードブロックをコピーして保存しtst.awk、

NR == FNR {
  pat[NR] = $0
  next
}

FNR == 1 {
  fil[c++] = FILENAME
}

{
  for (i in pat)
    if ($0 ~ pat[i])
      mat[FILENAME, pat[i]]++
}

END {
  for (i in fil)
    printf "\t%s", fil[i]

  print ""

  for (i in pat) {
    printf "%s", pat[i]

    for (j in fil)
      printf "\t%d", mat[fil[j], pat[i]]

    print ""
  }
}

そして、実行

awk -f tst.awk patterns file1 file2 file3

デモ：

$ seq 5 > file1
$ seq 3 7 > file2
$ seq 5 9 > file3
$ seq 3 2 7 > patterns
$ awk -f tst.awk patterns file1 file2 file3
        file1   file2   file3
3       1       1       0
5       1       1       1
7       0       1       1