Basic operations of ESP8266 flash file system - deleting files

1. Delete files

/*
 * 1、在NodeMCU中创建txt，并向其写入数据
 * 2、从闪存中读取已写入的数据
 * 3、向已有文件中添加信息
 */
#include <FS.h>

//文件操作的位置和名称
String fileName = "/MangoChips/Demo-01.txt";

//被读取的文件夹
String fileFolder = "/MangoChips";

void setup(){
  Serial.begin(9600);
  Serial.println("");

  Serial.println("SPIFFS format start");
  SPIFFS.format();//格式化文件系统
  Serial.println("SPIFFS format finish");

  //启动SPIFFS
  if(SPIFFS.begin()){
    Serial.println("SPIFFS Started");
  }else{
    Serial.println("SPIFFS Failed to Start");
    return;
  }
  
  WriteFiel();
  
  ReadFile(); 
  
  AddFile();
  
  ReadFile();

  ReadFolder();

  DeleteFile();

  ReadFile();
  
}

//1、写操作
void WriteFiel(){
  Serial.println("****************写操作开始******************");
  
  File writeFile = SPIFFS.open(fileName,"w");//建立File对象，并表示将要进行“写”操作
  writeFile.println("Hello to IOT by MangoChips");//写
  writeFile.close();//写操作完成后关闭文件
  
  Serial.println("SPIFFS Write Finished");
  Serial.println("****************写操作完成******************\n");
}

//2、读操作
void ReadFile(){
  Serial.println("****************读操作开始******************");
  
  if(SPIFFS.exists(fileName)){
    Serial.print(fileName);
    Serial.println(" Found");
    
    File readFile = SPIFFS.open(fileName,"r");
    for(int i = 0; i<readFile.size();i++){
      Serial.print((char)readFile.read());//一次读取一个字符
    }
    
  }else{
    Serial.print(fileName);
    Serial.println(" Not Found");
  }
  
  Serial.println("****************读操作完成******************\n");
}

//3、添加信息
void AddFile(){
  Serial.println("****************添加操作开始******************");
  
  if(SPIFFS.exists(fileName)){
    Serial.print(fileName);
    Serial.println(" Found");
    
    File addFile = SPIFFS.open(fileName,"a");
    addFile.println("Add Info!!");
    addFile.close();
    
    Serial.println("Finished Add Data to File");
  }else{
    Serial.print(fileName);
    Serial.println(" Not Found");
  }
  
  Serial.println("****************添加操作完成******************\n");
}

//4、读取目录内容
void ReadFolder(){
  Serial.println("****************读取目录操作开始******************");
  
  Dir dirPath = SPIFFS.openDir(fileFolder);
  while(dirPath.next()){
    Serial.println(dirPath.fileName());
  }
  Serial.println("****************读取目录操作完成******************\n");
}

//5、删除文件
void DeleteFile(){
  Serial.println("****************删除文件操作开始******************");
  
  if(SPIFFS.exists(fileName)){
    Serial.print(fileName);
    Serial.println(" Found");
    if(SPIFFS.remove(fileName)){
      Serial.print(fileName);
      Serial.println(" Remove Success");
    }else{
      Serial.print(fileName);
      Serial.println(" Remove fail");
    }
    
  }else{
    Serial.print(fileName);
    Serial.println(" Not Found");
  }
  Serial.println("****************删除文件操作完成******************\n");
}

void loop(){

}