Processing, how to redraw shapes when they dissappear

Zubair Ali :

Hi guys so i have this game made where the user avoids aliens coming from the right side of the screen and then they go past the left side. I need the aliens to reappear from the right side once they leave the left side of the screen. How can i go about doing this? Here is my existing code:

EDIT: Added alien class underneath main class

PImage background;
int x=0; //global variable background location

Alien alien1;
Alien alien2;
Alien alien3;
Defender user1;


void setup(){
 size(800,400);
 background = loadImage("spaceBackground.jpg");
 background.resize(width,height);

 alien1 = new Alien(800,100,5);
 alien2 = new Alien(800,200,5);
 alien3 = new Alien(800,300,5);

 user1 = new Defender(10,height/2);

}
void draw ()
{
 drawBackground();
 alien1.move();
 alien1.render();
 alien2.move();
 alien2.render();
 alien3.move();
 alien3.render();
 user1.render();
}  

void drawBackground()
{
 image(background, x, 0); //draw background twice adjacent
 image(background, x+background.width, 0);
 x -=4;
 if(x == -background.width)
 x=0; //wrap background
}

void keyPressed()
{

  if(key == CODED) {
     if (keyCode == UP) {
       user1.y = user1.y - 5;
     }
     else if (keyCode == DOWN)
     {
       user1.y = user1.y + 5;
     }
  }

}


final color Alien1 = color(0,255,0);
final color Alien2 = color(50,100,0);

class Alien
{
 int x,y;
 int speedX, speedY;

 Alien(int x, int y, int speedX)
 {
  this.x = x;
  this.y = y;
  this.speedX = speedX;
 }

 void move()
 {
   x=x-speedX;
   float stepY = random(-5,5);
   y = y + (int)stepY;
 }

 //draw an alien
 void render()
 {
 fill(Alien1);
 ellipse(x,y,30,30);
 fill(Alien2);
 ellipse(x,y,50,15);

 }



}

Xeno-D :

If you upload your Alien class then we can give clearer directions but the idea is that your should add the following logic in your move() method.

void move()
 {
   x=x-speedX;
   float stepY = random(-5,5);
   y = y + (int)stepY;
   if(this.x < 0) {
      this.x = 800; // or width, startingPosition, ...
   }
 }

Edit: Alien class was added so adapted my solution to the code.