WiFi-ESP8266入门开发(二十一)--ESP8266 OTA无线更新固件

注：对于ESP8266和ESP32开源技术感兴趣的可以加群，我们一起探索交流学习，群号：551636355。群名：ESP32开源技术交流群。

OTA - Over the air update of the firmware 即空中固件更新。这是乐鑫SDK中极为之Cool的功能！

平时做Arduino 或者 ESP8266的开发都要很苦逼地用USB插着板子，如果用ESP-01的话还得接FDTI232的转换板，更麻烦总之我很讨厌那根USB的数据线，无线总比有线的好！

上面这种只是在实验室环境下的情况，还有另一种最实际的应用：当我们的将实验环境中的ESP8266做成产品并交付到客户手上之时应该如何来更新产品中的ESP8266的固件呢？难到要用户拿到服务中心来更新？如果是这样那这个产品一是失败之作，而且也一定做不下去的，至少我们现在还没有遇到过这么坑爹的产品吧。这个时候OTA所能发挥的作用就非常大了，通过无线网络对固件进行重新的分发与更新是WIFI智能产品的一个最基本也是最重要的功能。

如果使用NodeMCU Lua 的话是没有这个功能的，NodeMCU的GitHub上这个问题被放在ISSUSE中很久了，至今还没有办法解决。但我曾找过一些相关的文献资料但也并不是很完美: ESP8266 OTA LUA with WEB UI MANAGEMENT / Nodemcu firmware

但如果你是用Arduino Core For ESP8266 的话这就是小菜一碟了。首先我们得先从理论入手，了解一下OTA的本质是什么它又是怎么样工作的。我们都知道，当使用串口线来更新ESP8266固件时是通过ESP8266中的SerialBootLoader来的进行引导与写入的，这是一种默认方式。OTA则是“绕过”了SerialBootLoader而通过WIFI向ESP8266中的"WIFI Boot Loader"进行通信，由WIFI Boot Loader 来引导无线固件写入更新。当然这个WIFI Boot Loader 就需要我们自已先通过串行线预先写入到的ESP8266中。换句话说，我们得在代码内嵌入用于OTA的 WIFI Boot Loader 。

悻然，这个过程并不需要我们来写，因为Arduino For ESP8266 已经为我们配置一个系列极棒的示例代码，其中就有OTA的WIFI Boot Loader 代码，只是它并不是叫这个名称而已。

好了理论很重要，但不如实践！我们直接动手，先试试将ESP8266做成可以支持OTA。

打开Arduino IDE 从示例菜单里面打开一个叫"BasicOTA" 项。

具体代码如下所示：

#include <ESP8266WiFi.h>
#include <ESP8266mDNS.h>
#include <WiFiUdp.h>
#include <ArduinoOTA.h>

const char* ssid = "..........";
const char* password = "..........";

void setup() {
  Serial.begin(115200);
  Serial.println("Booting");
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.waitForConnectResult() != WL_CONNECTED) {
    Serial.println("Connection Failed! Rebooting...");
    delay(5000);
    ESP.restart();
  }

  // Port defaults to 8266
  // ArduinoOTA.setPort(8266);

  // Hostname defaults to esp8266-[ChipID]
  // ArduinoOTA.setHostname("myesp8266");

  // No authentication by default
  // ArduinoOTA.setPassword("admin");

  // Password can be set with it's md5 value as well
  // MD5(admin) = 21232f297a57a5a743894a0e4a801fc3
  // ArduinoOTA.setPasswordHash("21232f297a57a5a743894a0e4a801fc3");

  ArduinoOTA.onStart([]() {
    String type;
    if (ArduinoOTA.getCommand() == U_FLASH) {
      type = "sketch";
    } else { // U_SPIFFS
      type = "filesystem";
    }

    // NOTE: if updating SPIFFS this would be the place to unmount SPIFFS using SPIFFS.end()
    Serial.println("Start updating " + type);
  });
  ArduinoOTA.onEnd([]() {
    Serial.println("\nEnd");
  });
  ArduinoOTA.onProgress([](unsigned int progress, unsigned int total) {
    Serial.printf("Progress: %u%%\r", (progress / (total / 100)));
  });
  ArduinoOTA.onError([](ota_error_t error) {
    Serial.printf("Error[%u]: ", error);
    if (error == OTA_AUTH_ERROR) {
      Serial.println("Auth Failed");
    } else if (error == OTA_BEGIN_ERROR) {
      Serial.println("Begin Failed");
    } else if (error == OTA_CONNECT_ERROR) {
      Serial.println("Connect Failed");
    } else if (error == OTA_RECEIVE_ERROR) {
      Serial.println("Receive Failed");
    } else if (error == OTA_END_ERROR) {
      Serial.println("End Failed");
    }
  });
  ArduinoOTA.begin();
  Serial.println("Ready");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

void loop() {
  ArduinoOTA.handle();
}

然后我们将SSPI和Password两个变量设定为你现在所接连的WIFI名称与密码：

const char* ssid = "你的WIFI连接名称";
const char* password = "你的WIFI密码";

然后果决地写入到你的ESP8266中。写入成功后，打开串口监视器你会看到如下的内容：

然后在工具菜单的端口项中你会发现多了一个 "esp8266-xxxxx 192.168.1.130" 的菜单项，选中它

然后，想看一下效果的话将Setup函数中的打印信息改一下，改成 "Read for OTA"，拔掉串口线，用外部电源接上ESP8266并启动它，等上20来秒后，在Arduino IDE上点击上传，盯着你的ESP8266看就会发现它的内置LED在烧写时狂闪，一切就大功告成了！

现在我们对上述的OTA代码进行一下分析就会发现它的实现逻辑其实非常的简单，主要是以下这么几步：

连接WIFI
配置 ArduinoOTA 对象的事件函数
启动 ArduinoOTA 服务 ArduinoOTA.begin()
在 loop() 函数将处理权交由 ArduinoOTA.handle()

清楚这个代码逻辑后，我们就可以按照实现的开发需要对其进行更改。例如可以加入一个标志位 flag，用于标识当前运行状态

flag = 0 普通工作模式
flag = 1 刷机模式

然后通过硬件（按钮）或者软件（如MQTT或其它通信协议）方式来控制这个标志位以控制ESP8266的运行模式：

void loop() {
  if (flag ==0 ) {
    // 正常工作状态的代码
  } else {
    ArduinoOTA.handle();
 }
}

这样我们就可以随时通过WIFI对ESP8266的固件进行更新了。

WiFi-ESP8266入门开发(二十一)--ESP8266 OTA无线更新固件

猜你喜欢